Fix various counters

lib/philomena/comments.ex

@@ -179,10 +179,26 @@ defmodule Philomena.Comments do
 
   """
   def destroy_comment(%Comment{} = comment) do
-    comment
-    |> Comment.destroy_changeset()
-    |> Repo.update()
-    |> reindex_after_update()
+    comment = comment |> Repo.preload(:user)
+
+    Multi.new()
+    |> Multi.update(:comment, Comment.destroy_changeset(comment))
+    |> Multi.update_all(
+      :image,
+      Image |> where(id: ^comment.image_id),
+      inc: [comments_count: -1]
+    )
+    |> Repo.transaction()
+    |> case do
+      {:ok, %{comment: comment}} ->
+        UserStatistics.inc_stat(comment.user, :comments_posted, -1)
+        reindex_comment(comment)
+
+        {:ok, comment}
+
+      error ->
+        error
+    end
   end
 
   defp reindex_after_update(result) do

lib/philomena/forums.ex

@@ -104,4 +104,27 @@ defmodule Philomena.Forums do
   def change_forum(%Forum{} = forum) do
     Forum.changeset(forum, %{})
   end
+
+  @doc """
+  Returns an `m:Ecto.Query` which updates the last post for the given forum.
+
+  ## Examples
+
+      iex> update_forum_last_post_query(1)
+      #Ecto.Query<...>
+
+  """
+  def update_forum_last_post_query(forum_id) do
+    Forum
+    |> where(id: ^forum_id)
+    |> update(
+      set: [
+        last_post_id:
+          fragment(
+            "SELECT max(posts.id) FROM posts JOIN topics ON posts.topic_id = topics.id WHERE topics.forum_id = ? AND topics.hidden_from_users IS FALSE AND posts.hidden_from_users IS FALSE",
+            ^forum_id
+          )
+      ]
+    )
+  end
 end

lib/philomena/posts.ex

@@ -10,6 +10,7 @@ defmodule Philomena.Posts do
   alias PhilomenaQuery.Search
   alias Philomena.Topics.Topic
   alias Philomena.Topics
+  alias Philomena.Forums
   alias Philomena.UserStatistics
   alias Philomena.Users.User
   alias Philomena.Posts.Post
@@ -208,25 +209,13 @@ defmodule Philomena.Posts do
 
   """
   def hide_post(%Post{} = post, attrs, user) do
-    report_query = Reports.close_report_query({"Post", post.id}, user)
-
-    topics =
-      Topic
-      |> where(last_post_id: ^post.id)
-      |> update(set: [last_post_id: nil])
-
-    forums =
-      Forum
-      |> where(last_post_id: ^post.id)
-      |> update(set: [last_post_id: nil])
-
-    post = Post.hide_changeset(post, attrs, user)
+    post = post |> Repo.preload(:topic)
 
     Multi.new()
-    |> Multi.update(:post, post)
-    |> Multi.update_all(:reports, report_query, [])
-    |> Multi.update_all(:topics, topics, [])
-    |> Multi.update_all(:forums, forums, [])
+    |> Multi.update(:post, Post.hide_changeset(post, attrs, user))
+    |> Multi.update_all(:reports, Reports.close_report_query({"Post", post.id}, user), [])
+    |> Multi.update_all(:topic, Topics.update_topic_last_post_query(post.topic_id), [])
+    |> Multi.update_all(:forum, Forums.update_forum_last_post_query(post.topic.forum_id), [])
     |> Repo.transaction()
     |> case do
       {:ok, %{post: post, reports: {_count, reports}}} ->
@@ -250,10 +239,22 @@ defmodule Philomena.Posts do
 
   """
   def unhide_post(%Post{} = post) do
-    post
-    |> Post.unhide_changeset()
-    |> Repo.update()
-    |> reindex_after_update()
+    post = post |> Repo.preload(:topic)
+
+    Multi.new()
+    |> Multi.update(:post, Post.unhide_changeset(post))
+    |> Multi.update_all(:topic, Topics.update_topic_last_post_query(post.topic_id), [])
+    |> Multi.update_all(:forum, Forums.update_forum_last_post_query(post.topic.forum_id), [])
+    |> Repo.transaction()
+    |> case do
+      {:ok, %{post: post}} ->
+        reindex_post(post)
+
+        {:ok, post}
+
+      error ->
+        error
+    end
   end
 
   @doc """
@@ -266,10 +267,31 @@ defmodule Philomena.Posts do
 
   """
   def destroy_post(%Post{} = post) do
-    post
-    |> Post.destroy_changeset()
-    |> Repo.update()
-    |> reindex_after_update()
+    post = post |> Repo.preload([:topic, :user])
+
+    Multi.new()
+    |> Multi.update(:post, Post.destroy_changeset(post))
+    |> Multi.update_all(
+      :topic,
+      Topic |> where(id: ^post.topic_id),
+      inc: [post_count: -1]
+    )
+    |> Multi.update_all(
+      :forum,
+      Forum |> where(id: ^post.topic.forum_id),
+      inc: [post_count: -1]
+    )
+    |> Repo.transaction()
+    |> case do
+      {:ok, %{post: post}} ->
+        UserStatistics.inc_stat(post.user, :forum_posts, -1)
+        reindex_post(post)
+
+        {:ok, post}
+
+      error ->
+        error
+    end
   end
 
   @doc """

lib/philomena/topics.ex

@@ -8,8 +8,10 @@ defmodule Philomena.Topics do
   alias Philomena.Repo
 
   alias Philomena.Topics.Topic
+  alias Philomena.Forums
   alias Philomena.Forums.Forum
   alias Philomena.Posts
+  alias Philomena.UserStatistics
   alias Philomena.Notifications
 
   use Philomena.Subscriptions,
@@ -77,6 +79,7 @@ defmodule Philomena.Topics do
     |> Repo.transaction()
     |> case do
       {:ok, %{topic: topic}} = result ->
+        UserStatistics.inc_stat(topic.user, :topics)
         Posts.reindex_post(hd(topic.posts))
         Posts.report_non_approved(hd(topic.posts))
 
@@ -205,26 +208,19 @@ defmodule Philomena.Topics do
   """
   def move_topic(topic, new_forum_id) do
     old_forum_id = topic.forum_id
-    topic_changes = Topic.move_changeset(topic, new_forum_id)
 
     Multi.new()
-    |> Multi.update(:topic, topic_changes)
-    |> Multi.run(:update_old_forum, fn repo, %{topic: topic} ->
-      {count, nil} =
-        Forum
-        |> where(id: ^old_forum_id)
-        |> repo.update_all(inc: [post_count: -topic.post_count, topic_count: -1])
-
-      {:ok, count}
-    end)
-    |> Multi.run(:update_new_forum, fn repo, %{topic: topic} ->
-      {count, nil} =
-        Forum
-        |> where(id: ^topic.forum_id)
-        |> repo.update_all(inc: [post_count: topic.post_count, topic_count: 1])
-
-      {:ok, count}
-    end)
+    |> Multi.update(:topic, Topic.move_changeset(topic, new_forum_id))
+    |> Multi.update_all(
+      :old_forum,
+      Forums.update_forum_last_post_query(old_forum_id),
+      inc: [post_count: -topic.post_count, topic_count: -1]
+    )
+    |> Multi.update_all(
+      :new_forum,
+      Forums.update_forum_last_post_query(new_forum_id),
+      inc: [post_count: topic.post_count, topic_count: 1]
+    )
     |> Repo.transaction()
   end
 
@@ -238,20 +234,20 @@ defmodule Philomena.Topics do
 
   """
   def hide_topic(topic, deletion_reason, user) do
-    topic_changes = Topic.hide_changeset(topic, deletion_reason, user)
-
-    forums =
-      Forum
-      |> join(:inner, [f], _ in assoc(f, :last_post))
-      |> where([f, p], p.topic_id == ^topic.id)
-      |> update(set: [last_post_id: nil])
+    topic = topic |> Repo.preload(:user)
 
     Multi.new()
-    |> Multi.update(:topic, topic_changes)
-    |> Multi.update_all(:forums, forums, [])
+    |> Multi.update(:topic, Topic.hide_changeset(topic, deletion_reason, user))
+    |> Multi.update_all(
+      :forum,
+      Forums.update_forum_last_post_query(topic.forum_id),
+      inc: [post_count: -topic.post_count, topic_count: -1]
+    )
     |> Repo.transaction()
     |> case do
       {:ok, %{topic: topic}} ->
+        UserStatistics.inc_stat(topic.user, :topics, -1)
+
         {:ok, topic}
 
       error ->
@@ -269,8 +265,25 @@ defmodule Philomena.Topics do
 
   """
   def unhide_topic(topic) do
-    Topic.unhide_changeset(topic)
-    |> Repo.update()
+    topic = topic |> Repo.preload(:user)
+
+    Multi.new()
+    |> Multi.update(:topic, Topic.unhide_changeset(topic))
+    |> Multi.update_all(
+      :forum,
+      Forums.update_forum_last_post_query(topic.forum_id),
+      inc: [post_count: topic.post_count, topic_count: 1]
+    )
+    |> Repo.transaction()
+    |> case do
+      {:ok, %{topic: topic}} ->
+        UserStatistics.inc_stat(topic.user, :topics)
+
+        {:ok, topic}
+
+      error ->
+        error
+    end
   end
 
   @doc """
@@ -302,4 +315,27 @@ defmodule Philomena.Topics do
     Notifications.clear_forum_topic_notification(topic, user)
     :ok
   end
+
+  @doc """
+  Returns an `m:Ecto.Query` which updates the last post for the given topic.
+
+  ## Examples
+
+      iex> update_topic_last_post_query(1)
+      #Ecto.Query<...>
+
+  """
+  def update_topic_last_post_query(topic_id) do
+    Topic
+    |> where(id: ^topic_id)
+    |> update(
+      set: [
+        last_post_id:
+          fragment(
+            "SELECT max(id) FROM posts WHERE topic_id = ? AND hidden_from_users IS FALSE",
+            ^topic_id
+          )
+      ]
+    )
+  end
 end

lib/philomena/user_statistics.ex

@@ -32,7 +32,8 @@ defmodule Philomena.UserStatistics do
              :comments_posted,
              :votes_cast,
              :metadata_updates,
-             :forum_posts
+             :forum_posts,
+             :topics
            ] do
     now =
       DateTime.utc_now()

lib/philomena/user_statistics/user_statistic.ex

@@ -4,16 +4,18 @@ defmodule Philomena.UserStatistics.UserStatistic do
 
   alias Philomena.Users.User
 
-  # fixme: rekey this on (user_id, day)
+  @primary_key false
+
   schema "user_statistics" do
-    belongs_to :user, User
-    field :day, :integer, default: 0
+    belongs_to :user, User, primary_key: true
+    field :day, :integer, default: 0, primary_key: true
     field :uploads, :integer, default: 0
     field :votes_cast, :integer, default: 0
     field :comments_posted, :integer, default: 0
     field :metadata_updates, :integer, default: 0
     field :images_favourited, :integer, default: 0
     field :forum_posts, :integer, default: 0
+    field :topics, :integer, default: 0
   end
 
   @doc false
@@ -25,7 +27,8 @@ defmodule Philomena.UserStatistics.UserStatistic do
       :comments_posted,
       :metadata_updates,
       :images_favourited,
-      :forum_posts
+      :forum_posts,
+      :topics
     ])
   end
 end

lib/philomena/users/user.ex

@@ -96,7 +96,7 @@ defmodule Philomena.Users.User do
 
     # Counters
     field :forum_posts_count, :integer, default: 0
-    field :topic_count, :integer, default: 0
+    field :topics_count, :integer, default: 0
     field :uploads_count, :integer, default: 0
     field :votes_cast_count, :integer, default: 0
     field :comments_posted_count, :integer, default: 0

lib/philomena_web/views/api/json/profile_view.ex

@@ -17,7 +17,7 @@ defmodule PhilomenaWeb.Api.Json.ProfileView do
       comments_count: user.comments_posted_count,
       uploads_count: user.uploads_count,
       posts_count: user.forum_posts_count,
-      topics_count: user.topic_count,
+      topics_count: user.topics_count,
       links:
         render_many(
           user.public_links,

priv/repo/migrations/20250430092058_user_statistics_new_pk.exs

@@ -0,0 +1,12 @@
+defmodule Philomena.Repo.Migrations.UserStatisticsNewPk do
+  use Ecto.Migration
+
+  # Not reversible because we're removing the primary key and the associated sequence.
+  def up do
+    alter table(:user_statistics) do
+      remove :id
+      modify :user_id, :integer, primary_key: true
+      modify :day, :integer, primary_key: true
+    end
+  end
+end