通过编译时字符串，调用到某实例的方法

[jiacai2050]

const std = @import("std");

const MyStruct = struct {
    value: i32,

    pub fn print(self: *const MyStruct) void {
        std.debug.print("Value: {}\n", .{self.value});
    }
};

fn callMethod(comptime T: type, comptime method_name: []const u8, obj: T, args: anytype) void {
    if (!@hasDecl(T, method_name)) {
        @compileError("Method '" ++ method_name ++ "' not found");
    }

    const method = @field(T, method_name);
    @call(.auto, method, .{&obj} ++ args);
}

pub fn main() !void {
    const my_obj = MyStruct{ .value = 10 };

    // 通过字符串调用方法
    callMethod(MyStruct, "print", my_obj, .{});
}

• https://codapi.org/embed/?sandbox=zig&code=data%3A%3Bbase64%2CXVHLSsNAFN3PVxxnoYmG1MdGEgpd6NKVxY1KyWPSTklmQjIplBIQXPgDPsAPEBcKohtd%2BTM%2B6l%2FIZFqtZpNk5p7XPZEUpUKpYrTR4VkuC2XRUsXU9gmJmsu98b4qqkihjdJ8TAgAjIK0Yh741qZDmoO8CpEI5AUXyipZmnhY%2FUthYyR5PMPrp1SxG7Ow6rsGRQ8M6aQ%2BEtSBO9E0bqNU234Dq0ntE5IIREGa7jE1kLEVySxXPGPoelDjnDn4OcmaiZ4IMubh8Nj4qbYdyHDooesgKPqlh0CMNfCPQZ7AWuoMgnKHRanVdRa5bHshRUer8ZTtFoUsLGpMYYVibW0Ro3%2FpCoRUSGQlmh2bRM3LWDPzuo2EszT%2BL2sQHZ3dcoNKyfm1XtayDIe1VtGZbJ%2FUhMw6yQIuLBtLC%2BlmcuOeDIdo%2F1Q0gVk32thYh161Hm618HVyPX09e7%2B%2F%2Bry7eXt%2BnD6cfp7ffly%2BfDxdGL7fOuZcDmhTK3VmOtqk7rH%2BBg%3D%3D

[happystraw]

加一个可以有返回值， 在线运行

const std = @import("std");

const MyStruct = struct {
    value: i32,

    pub fn print(self: *const MyStruct) void {
        std.debug.print("Value: {}\n", .{self.value});
    }

    pub fn add(self: *MyStruct, num: i32) i32 {
        self.value += num;
        return self.value;
    }
};

fn callMethod(comptime T: type, obj: anytype, comptime method: []const u8, args: anytype) T {
    const ObjType = @TypeOf(obj);
    const obj_type_info = @typeInfo(ObjType);
    const is_pointer, const ActualType = blk: {
        switch (obj_type_info) {
            .pointer => break :blk .{ true, obj_type_info.pointer.child },
            else => break :blk .{ false, ObjType },
        }
    };
    if (!@hasDecl(ActualType, method)) {
        @compileError("Method '" ++ method ++ "' not found in type '" ++ @typeName(ObjType) ++ "'");
    }
    const ptr = if (is_pointer) obj else &obj;
    const func = @field(ActualType, method);
    return @call(.auto, func, .{ptr} ++ args);
}

pub fn main() void {
    var obj = MyStruct{ .value = 10 };
    // with return value
    const result = callMethod(i32, &obj, "add", .{5});
    std.debug.print("Result of add: {}\n", .{result});
    // without return value
    callMethod(void, obj, "print", .{});
}