如何正确 free memory ?

[daiwhea]

本来是想要解析一个 xls 文件，然后 将其中的数据创建一个 StringHashMap ，但在 free 创建的 string 的时候出现个问题，前面 6 次循环运行正确 free，第七次 会报错。报错如下：

zig test src/ss.zig
Test [1/1] ss.test.test memory free... 
 => i 0 scode sh600001
 => i 1 scode sh600002
 => i 2 scode sh600003
 => i 3 scode sh600004
 => i 4 scode sh600005
 => i 5 scode sh600006
 => i 6 scode sh600007
Segmentation fault at address 0x1013e4000
/Users/mac/dev/zig-macos-x86_64-0.12.0-dev.3052+4e2570baa/lib/std/hash/wyhash.zig:134:48: 0x10121d874 in hash (test)
        return @as(u64, std.mem.readInt(T, data[0..bytes], .little));
                                               ^
Unwind error at address `test:0x10121d874` (error.InvalidUnwindInfo), trace may be incomplete

error: the following test command crashed:
/Users/mac/myworks/zig/xls/zig-cache/o/fda191d5901d9acf08c850ea490f01ba/test

为了方便debug【避免使用 xls 解析相关的 libxls c代码】另外写了个测试用的 demo，也会同样的错误。没有思路跟进了。敬请指教。 ^-^

代码如下：

const std = @import("std");

pub const Scode = [8]u8;

pub const Sname = []const u8;

pub const ScodeNameMap = std.StringHashMap(Sname);

const scodes = [_][6]u8{
    [_]u8{ '6', '0', '0', '0', '0', '1' },
    [_]u8{ '6', '0', '0', '0', '0', '2' },
    [_]u8{ '6', '0', '0', '0', '0', '3' },
    [_]u8{ '6', '0', '0', '0', '0', '4' },
    [_]u8{ '6', '0', '0', '0', '0', '5' },
    [_]u8{ '6', '0', '0', '0', '0', '6' },
    [_]u8{ '6', '0', '0', '0', '0', '7' },
    [_]u8{ '6', '0', '0', '0', '0', '8' },
    [_]u8{ '6', '0', '0', '0', '0', '9' },
};

fn getScode(allocator: std.mem.Allocator, str1: []const u8, str2: []const u8) ![]const u8 {
    const buff_len = str1.len + str2.len;
    var buff = try allocator.alloc(u8, buff_len);
    @memcpy(buff[0..str1.len], str1);
    @memcpy(buff[str1.len..buff_len], str2);
    return buff;
}

test "test memory free" {
    const allocator = std.testing.allocator;
    var res = ScodeNameMap.init(allocator);
    std.debug.print("\n", .{});
    for (0..9) |i| {
        const scode = try getScode(allocator, "sh", &scodes[i]);
        std.debug.print(" => i {d} scode {s}\n", .{ i, scode });
        try res.put(scode, scode);
        allocator.free(scode); // 此处不管加不加 defer 都会在第七次 free 的时候出错
    }
    std.debug.print("\nres count {d}\n\n", .{res.count()});
}

[zhangkaizhao]

const std = @import("std");

pub const Scode = [8]u8;

pub const Sname = []const u8;

pub const ScodeNameMap = std.StringHashMap(Sname);

const scodes = [_][6]u8{
    [_]u8{ '6', '0', '0', '0', '0', '1' },
    [_]u8{ '6', '0', '0', '0', '0', '2' },
    [_]u8{ '6', '0', '0', '0', '0', '3' },
    [_]u8{ '6', '0', '0', '0', '0', '4' },
    [_]u8{ '6', '0', '0', '0', '0', '5' },
    [_]u8{ '6', '0', '0', '0', '0', '6' },
    [_]u8{ '6', '0', '0', '0', '0', '7' },
    [_]u8{ '6', '0', '0', '0', '0', '8' },
    [_]u8{ '6', '0', '0', '0', '0', '9' },
};

fn getScode(allocator: std.mem.Allocator, str1: []const u8, str2: []const u8) ![]const u8 {
    const buff_len = str1.len + str2.len;
    var buff = try allocator.alloc(u8, buff_len);
    @memcpy(buff[0..str1.len], str1);
    @memcpy(buff[str1.len..buff_len], str2);
    return buff;
}

test "test memory free" {
    const allocator = std.testing.allocator;
    var res = ScodeNameMap.init(allocator);
    // https://ziglang.org/documentation/master/std/#std.hash_map.StringHashMap
    // > Builtin hashmap for strings as keys.
    // > Key memory is managed by the caller.
    // > Keys and values will not automatically be freed.
    // https://ziglang.org/documentation/master/std/#std.hash_map.HashMap.deinit
    // > Release the backing array and invalidate this map.
    // > This does not deinit keys, values, or the context!
    // > If your keys or values need to be released, ensure that that is done before calling this function.
    defer res.deinit();

    std.debug.print("\n", .{});
    for (0..9) |i| {
        const scode = try getScode(allocator, "sh", &scodes[i]);
        std.debug.print(" => i {d} scode {s}\n", .{ i, scode });
        try res.put(scode, scode);
    }
    std.debug.print("\nres count {d}\n\n", .{res.count()});

    var it = res.iterator();
    while (it.next()) |kv| {
        allocator.free(kv.key_ptr.*);
    }
}

$ zig test string_hash_map.zig
Test [1/1] string_hash_map.test.test memory free... 
 => i 0 scode sh600001
 => i 1 scode sh600002
 => i 2 scode sh600003
 => i 3 scode sh600004
 => i 4 scode sh600005
 => i 5 scode sh600006
 => i 6 scode sh600007
 => i 7 scode sh600008
 => i 8 scode sh600009

res count 9

All 1 tests passed.

[daiwhea]

谢谢啊，我这里理解似乎有问题。我在 lib/std/hash_map.zig 看到下面代码：

        pub fn getOrPutContext(self: *Self, allocator: Allocator, key: K, ctx: Context) Allocator.Error!GetOrPutResult {
            const gop = try self.getOrPutContextAdapted(allocator, key, ctx, ctx);
            if (!gop.found_existing) {
                gop.key_ptr.* = key; // 这里，我以为是直接复制 key 的内容到 gop.key_ptr 了。所以以为不再需要自己维护保存在 HashMap 里面的 key/value 了。貌似 自己对zig的指针的理解 还是不够
            }
            return gop;
        }

谢谢啊。搜一下相关内容看看先。