Fix unnecessarily setting gluster volume option repeatedly

Checks Gluster volume options against existing values to avoid repeatedly
setting values

Also adds these types:
+ `Gluster::VolumeName`
+ `Gluster::VolumeOption`

And these functions:
+ `gluster::cmd_volume_get_option`
+ `gluster::onoff`

Author: runejuhl

functions/cmd_volume_get_option.pp

@@ -0,0 +1,34 @@
+# Create a command string to get option `$opt` from gluster volume `$vol`, and
+# optionally compare it against `$comparison`.
+#
+# @param vol [Gluster::VolumeName] Gluster volume name
+# @param opt [Gluster::OptionName] Gluster volume option name
+# @param comparison [Optional[String]] Optional string to compare the existing
+#   value against
+# @return [String]
+#
+# @example Usage
+#
+#   ```puppet
+#   gluster::cmd_volume_get_option('data', 'nfs.disable', String(true))
+#   ```
+#
+function gluster::cmd_volume_get_option(
+  Gluster::VolumeName   $vol,
+  Gluster::VolumeOption $opt,
+  Optional              $comparison = undef,
+) {
+  $_cmd = "${::gluster_binary} volume get ${vol} ${opt}"
+
+  unless $comparison {
+    return $_cmd
+  }
+
+  $_comparison = $comparison ? {
+    Undef   => '\(null\)',
+    Boolean => gluster::onoff($comparison),
+    default => $comparison,
+  }
+
+  "${_cmd} | tail -n1 | grep -E '^${opt} +${_comparison} *\$'"
+}

functions/onoff.pp

@@ -0,0 +1,9 @@
+function gluster::onoff (
+  Boolean $value,
+) {
+  if $value {
+    'on'
+  } else {
+    'off'
+  }
+}

manifests/volume/option.pp

@@ -33,26 +33,34 @@
 # Copyright 2014 CoverMyMeds, unless otherwise noted
 #
 define gluster::volume::option (
-  $value  = undef,
-  $ensure = true,
+  Optional $value  = undef,
+  Boolean  $ensure = true,
 ) {
 
-  $arr = split( $title, ':' )
-  $count = count($arr)
+  $arr = $title.split(':')
   # do we have more than one array element?
-  if $count != 2 {
+  if count($arr) != 2 {
     fail("${title} does not parse as volume:option")
   }
-  $vol = $arr[0]
-  $opt = $arr[1]
+  [$vol, $opt] = $arr
 
-  if $ensure == 'absent' {
-    $cmd = "reset ${vol} ${opt}"
+  $cmd = if $ensure == 'absent' {
+    "reset ${vol} ${opt}"
   } else {
-    $cmd = "set ${vol} ${opt} ${value}"
+    "set ${vol} ${opt} ${value}"
+  }
+
+  $_value = if $value =~ Boolean {
+    gluster::onoff($value)
+  } else {
+    String($value)
   }
 
   exec { "gluster option ${vol} ${opt} ${value}":
+    path    => '/usr/bin:/usr/sbin:/bin',
     command => "${::gluster_binary} volume ${cmd}",
+    unless  => unless $ensure == 'absent' {
+      gluster::cmd_volume_get_option($vol, $opt, $_value)
+    },
   }
 }

types/volumename.pp

@@ -0,0 +1 @@
+type Gluster::VolumeName = Pattern[/^[a-zA-Z0-9_-]+$/]

types/volumeoption.pp

@@ -0,0 +1 @@
+type Gluster::VolumeOption = Pattern[/^[a-zA-Z0-9]+\.[a-zA-Z0-9-]+$/]