Merge pull request #31 from purescript/field-parity

Add Field Parity instance, resolves #30

Author: hdgarrood

src/Data/Int.purs

@@ -80,6 +80,28 @@ fromString :: String -> Maybe Int
 fromString = fromStringAs (Radix 10)
 
 -- | A type for describing whether an integer is even or odd.
+-- |
+-- | The `Ord` instance considers `Even` to be less than `Odd`.
+-- |
+-- | The `Semiring` instance allows you to ask about the parity of the results
+-- | of arithmetical operations, given only the parities of the inputs. For
+-- | example, the sum of an odd number and an even number is odd, so
+-- | `Odd + Even == Odd`. This also works for multiplication, eg. the product
+-- | of two odd numbers is odd, and therefore `Odd * Odd == Odd`.
+-- |
+-- | More generally, we have that
+-- |
+-- | ```purescript
+-- | parity x + parity y == parity (x + y)
+-- | parity x * parity y == parity (x * y)
+-- | ```
+-- |
+-- | for any integers `x`, `y`. (A mathematician would say that `parity` is a
+-- | *ring homomorphism*.)
+-- |
+-- | After defining addition and multiplication on `Parity` in this way, the
+-- | `Semiring` laws now force us to choose `zero = Even` and `one = Odd`.
+-- | This `Semiring` instance actually turns out to be a `Field`.
 data Parity = Even | Odd
 
 derive instance eqParity :: Eq Parity
@@ -93,6 +115,29 @@ instance boundedParity :: Bounded Parity where
   bottom = Even
   top = Odd
 
+instance semiringParity :: Semiring Parity where
+  zero = Even
+  add x y = if x == y then Even else Odd
+  one = Odd
+  mul Odd Odd = Odd
+  mul _ _ = Even
+
+instance ringParity :: Ring Parity where
+  sub = add
+
+instance commutativeRingParity :: CommutativeRing Parity
+
+instance euclideanRingParity :: EuclideanRing Parity where
+  degree Even = 0
+  degree Odd = 1
+  div x _ = x
+  mod _ _ = Even
+
+instance divisionRingParity :: DivisionRing Parity where
+  recip = id
+
+instance fieldParity :: Field Parity
+
 -- | Returns whether an `Int` is `Even` or `Odd`.
 -- |
 -- | ``` purescript

test/Test/Data/Int.purs

@@ -5,7 +5,7 @@ import Prelude
 import Control.Monad.Eff (Eff)
 import Control.Monad.Eff.Console (CONSOLE, log)
 
-import Data.Int (odd, even, fromString, floor, ceil, round, toNumber, fromNumber, fromStringAs, binary, octal, hexadecimal, radix, toStringAs, pow)
+import Data.Int (parity, odd, even, fromString, floor, ceil, round, toNumber, fromNumber, fromStringAs, binary, octal, hexadecimal, radix, toStringAs, pow)
 import Data.Maybe (Maybe(..), fromJust)
 
 import Global (nan, infinity)
@@ -136,6 +136,21 @@ testInt = do
   assert $ odd 4 == false
   assert $ odd 100 == false
 
+  log "parity is a ring homomorphism"
+  do
+    let go x y = do
+          assert $ parity x + parity y == parity (x + y)
+          assert $ parity x * parity y == parity (x * y)
+
+    go 0 0
+    go 0 1
+    go 1 0
+    go 1 1
+    go 2 28
+    go 2 3
+    go 3 8
+    go 49 171
+
   log "pow"
   assert $ pow 2 2 == 4
   assert $ pow 5 3 == 125