add a way to download a dependency

Author: lemz1

polymod/Polymod.hx

@@ -1166,6 +1166,11 @@ enum abstract PolymodErrorCode(String) from String to String
 	 */
 	var DEPENDENCY_CHECK_SKIPPED:String = 'dependency_check_skipped';
 
+	/**
+	 * Polymod attempted to download a mod, but it failed to do so.
+	 */
+	var DEPENDENCY_NOT_DOWNLOADABLE:String = 'dependency_not_downloadable';
+
 	/**
 	 * The given mod's API version does not match the version rule passed to Polymod.init.
 	 * - This generally indicates the mod is outdated and should be updated by the author.

polymod/util/DependencyUtil.hx

@@ -1,7 +1,12 @@
 package polymod.util;
 
+import haxe.Http;
+import haxe.io.Bytes;
+import haxe.zip.Reader;
 import polymod.Polymod.ModDependencies;
 import polymod.Polymod.ModMetadata;
+import sys.FileSystem;
+import sys.io.File;
 import thx.semver.VersionRule;
 
 /**
@@ -336,4 +341,86 @@ class DependencyUtil
 
 		return result;
 	}
+
+	/**
+	 * Given a github url and commit hash, download the dependency.
+	 * This is done using an http request.
+	 * @param outputDir the directory to download the dependency to
+	 * @param url github repository url: https://github.com/OWNER/REPOSITORY
+	 * @param commit commit hash 
+	 */
+	public static function downloadDependency(outputDir:String, url:String, commit:String):Void
+	{
+		var zipBytes:Null<Bytes> = getDependencyAsZip(url, commit);
+
+		if (zipBytes == null || zipBytes.length == 0)
+			return;
+
+		var reader = new Reader(new haxe.io.BytesInput(zipBytes));
+		var entries = reader.read();
+
+		if (!FileSystem.exists(outputDir))
+		{
+			FileSystem.createDirectory(outputDir);
+		}
+
+		for (entry in entries)
+		{
+			var fileName = entry.fileName;
+			if (entry.fileSize > 0)
+			{
+				var content = entry.data;
+				var filePath = outputDir + "/" + fileName;
+
+				var dirs = fileName.split("/");
+				dirs.pop();
+				var currentDir = outputDir;
+				for (dir in dirs)
+				{
+					currentDir += "/" + dir;
+					if (!FileSystem.exists(currentDir))
+					{
+						FileSystem.createDirectory(currentDir);
+					}
+				}
+
+				File.saveBytes(filePath, content);
+				trace("Extracted: " + filePath);
+			}
+		}
+
+		trace("Extraction complete. Files saved in: " + outputDir);
+	}
+
+	/**
+	 * Get the bytes of a dependency as a zip file.
+	 * @param url github repository url: https://github.com/OWNER/REPOSITORY
+	 * @param commit commit hash 
+	 * @return Null<Bytes>
+	 */
+	public static function getDependencyAsZip(url:String, commit:String):Null<Bytes>
+	{
+		// url structure of the code to download
+		// https://codeload.github.com/OWNER/REPOSITORY/zip/COMMIT
+
+		var urlSplit = url.split('/');
+		var repository = urlSplit[urlSplit.length - 1];
+		var owner = urlSplit[urlSplit.length - 2];
+
+		var downloadUrl = 'https://codeload.github.com/${owner}/${repository}/zip/${commit}';
+
+		var zipBytes:Null<Bytes> = null;
+
+		var http = new Http(downloadUrl);
+		http.onBytes = function(bytes:Bytes)
+		{
+			zipBytes = bytes;
+		}
+		http.request(false);
+
+		if (zipBytes == null || zipBytes.length == 0)
+			Polymod.error(DEPENDENCY_NOT_DOWNLOADABLE, 'Failed to download dependency: ${downloadUrl}');
+
+		return zipBytes;
+	}
 }