Add support for crtbegin and crtend

crtbegin is responsible for:
- Calling __register_frame_info which is used by old unwinders.
  We disable this behavior because we compile libunwind which
  discovers .eh_frame using dl_iterate_phdr.
- Calling .ctors callbacks if CRT doesn't do it
  In newer compiler .ctors section is placed after .init_array
  and callbacks are called as if they were from .init_array by the CRT).
  We disable this behavior because our CRT has support for .init_array
  and our linker places .ctors next to .init_array.
- Calling __cxa_finalize for the current dso_handle. Which calls
  destructors registerd by __cxa_atexit.
  We want this behavior.

Author: cerisier

runtimes/compiler-rt/BUILD.bazel

@@ -3,3 +3,15 @@ alias(
     actual = "@compiler-rt//:clang_rt.builtins.static",
     visibility = ["//visibility:public"],
 )
+
+alias(
+    name = "clang_rt.crtbegin",
+    actual = "@compiler-rt//:clang_rt.crtbegin.static",
+    visibility = ["//visibility:public"],
+)
+
+alias(
+    name = "clang_rt.crtend",
+    actual = "@compiler-rt//:clang_rt.crtend.static",
+    visibility = ["//visibility:public"],
+)

third_party/llvm-project/20.1.5/compiler-rt/BUILD.tpl

@@ -431,3 +431,49 @@ cc_stage2_static_library(
     ],
     visibility = ["//visibility:public"],
 )
+
+CRT_CFLAGS = [
+    "-std=c11",
+    "-fPIC",
+]
+
+CRT_DEFINES = [
+    "CRT_HAS_INITFINI_ARRAY",
+    "CRT_USE_FRAME_REGISTRY",
+]
+
+cc_stage2_library(
+    name = "clang_rt.crtbegin",
+    srcs = [
+        "lib/builtins/crtbegin.c",
+    ],
+    copts = CRT_CFLAGS,
+    local_defines = CRT_DEFINES,
+    visibility = ["//visibility:public"],
+)
+
+cc_stage2_static_library(
+    name = "clang_rt.crtbegin.static",
+    deps = [
+        ":clang_rt.crtbegin",
+    ],
+    visibility = ["//visibility:public"],
+)
+
+cc_stage2_library(
+    name = "clang_rt.crtend",
+    srcs = [
+        "lib/builtins/crtend.c",
+    ],
+    copts = CRT_CFLAGS,
+    local_defines = CRT_DEFINES,
+    visibility = ["//visibility:public"],
+)
+
+cc_stage2_static_library(
+    name = "clang_rt.crtend.static",
+    deps = [
+        ":clang_rt.crtend",
+    ],
+    visibility = ["//visibility:public"],
+)

toolchain/BUILD.bazel

@@ -44,6 +44,7 @@ cc_args_list(
         ],
         "@platforms//os:linux": [
             "//toolchain/args/linux:crt1",
+            "//toolchain/args/linux:crtbegin",
             "//toolchain/args/linux:linux_default_libs",
         ],
         "//conditions:default": [],
@@ -133,12 +134,26 @@ cc_toolchain(
         "@rules_cc//cc/toolchains/args:experimental_replace_legacy_action_config_features",
         "//toolchain/features:all_non_legacy_builtin_features",
         "//toolchain/features/legacy:all_legacy_builtin_features",
-    ],
+    ] + select({
+        # Should be last. This is a workaround to add those args last.
+        # See comment of this target.
+        "@platforms//os:linux": [
+            "//toolchain/args/linux:crtend_feature",
+        ],
+        "//conditions:default": [],
+    }),
     enabled_features = [
         "@rules_cc//cc/toolchains/args:experimental_replace_legacy_action_config_features",
         # Do not enable this manually. Those features are enabled internally by --compilation_mode flags family.
         "//toolchain/features/legacy:all_legacy_builtin_features",
-    ],
+    ] + select({
+        # Should be last. This is a workaround to add those args last.
+        # See comment of this target.
+        "@platforms//os:linux": [
+            "//toolchain/args/linux:crtend_feature",
+        ],
+        "//conditions:default": [],
+    }),
     tool_map = "//toolchain/llvm:all_tools",
     compiler = "clang",
 )

toolchain/args/linux/BUILD.bazel

@@ -1,5 +1,6 @@
 
 load("@rules_cc//cc/toolchains:args.bzl", "cc_args")
+load("@rules_cc//cc/toolchains:feature.bzl", "cc_feature")
 load("@rules_cc//cc/toolchains/impl:documented_api.bzl", "cc_args_list")
 
 package(default_visibility = ["//visibility:public"])
@@ -276,6 +277,57 @@ alias(
     })
 )
 
+cc_args(
+    name = "crtbegin",
+    actions = [
+        "@rules_cc//cc/toolchains/actions:link_actions",
+    ],
+    args = [
+        "-Wl,--whole-archive",
+        "{crtbegin}",
+        "-Wl,--no-whole-archive",
+    ],
+    format = {
+        "crtbegin": "//runtimes/compiler-rt:clang_rt.crtbegin",
+    },
+    data = [
+        "//runtimes/compiler-rt:clang_rt.crtbegin",
+    ],
+)
+
+#FIXME: Remove this
+# crtbegin and crtend must wrap all libraries_to_link but for now, we can't
+# use libraries_to_link as args because of legacy features not yet ported to args.
+#
+# As soon as it is the case, we can remove this cc_feature and use libraries_to_link
+# as args in the cc_toolchain args attributes, wrapped between crtbegin and crtend.
+cc_feature(
+    name = "crtend_feature",
+    feature_name = "crtend",
+    args = [
+        "//toolchain/args/linux:crtend",
+    ],
+    visibility = ["//visibility:public"],
+)
+
+cc_args(
+    name = "crtend",
+    actions = [
+        "@rules_cc//cc/toolchains/actions:link_actions",
+    ],
+    args = [
+        "-Wl,--whole-archive",
+        "{crtend}",
+        "-Wl,--no-whole-archive",
+    ],
+    format = {
+        "crtend": "//runtimes/compiler-rt:clang_rt.crtend",
+    },
+    data = [
+        "//runtimes/compiler-rt:clang_rt.crtend",
+    ],
+)
+
 alias(
     name = "linux_default_libs",
     actual = select({