adds query deriving from types #66

Author: roryc89

Diff for: src/GraphQL/Client/GetFields.purs

@@ -0,0 +1,52 @@
+-- | Get the graphql fields from a data type
+module GraphQL.Client.GetFields (class GetFieldsStandard, PropGetFieldsStandard, getFieldsStandard) where
+
+import Prelude
+
+import Data.HeytingAlgebra (class HeytingAlgebraRecord, tt)
+import Data.Maybe (Maybe)
+import Heterogeneous.Mapping (class HMap, class Mapping, hmap)
+import Prim.RowList (class RowToList)
+import Type.Proxy (Proxy(..))
+
+class GetFieldsStandard :: forall k. k -> Type -> Constraint
+class GetFieldsStandard t fields | t -> fields where
+  getFieldsStandard :: Proxy t -> fields
+
+data PropGetFieldsStandard
+  = PropGetFieldsStandard
+
+data PropToProxy
+  = PropToProxy
+
+instance getFieldsStandardRecord ::
+  ( RowToList r t
+  , HeytingAlgebraRecord t r r
+  , HMap PropGetFieldsStandard { | r } fields
+  , HMap PropGetFieldsStandard { | input } { | r }
+  ) =>
+  GetFieldsStandard { | input } fields where
+  getFieldsStandard _ = recordGetFieldsStandard (tt :: { | r })
+else instance getFieldsStandardMaybe :: GetFieldsStandard a fields => GetFieldsStandard (Maybe a) fields where
+  getFieldsStandard _ = getFieldsStandard (Proxy :: _ a)
+else instance getFieldsStandardArray :: GetFieldsStandard a fields => GetFieldsStandard (Array a) fields where
+  getFieldsStandard _ = getFieldsStandard (Proxy :: _ a)
+else instance getFieldsStandardLeaf :: GetFieldsStandard a Unit where
+  getFieldsStandard _ = unit
+
+
+instance propToProxy ::
+  Mapping PropToProxy t (Proxy t) where
+  mapping PropToProxy _ = Proxy
+
+recordGetFieldsStandard ::
+  forall t fields.
+  HMap PropGetFieldsStandard ({ | t }) fields => { | t } -> fields
+recordGetFieldsStandard = hmap PropGetFieldsStandard
+
+
+instance propGetFieldsStandard ::
+  (GetFieldsStandard t fields) =>
+  Mapping PropGetFieldsStandard t fields where
+  mapping PropGetFieldsStandard _ = getFieldsStandard (Proxy :: _ t)
+

Diff for: test/GraphQL/Client/GetFields.Test.purs

@@ -0,0 +1,53 @@
+module GraphQL.Client.GetFields.Test where
+
+import Prelude
+import Data.Argonaut.Core (Json)
+import Data.DateTime (DateTime)
+import Data.Maybe (Maybe)
+import GraphQL.Client.GetFields (getFieldsStandard)
+import Type.Proxy (Proxy(..))
+
+-- Type level tests 
+type User
+  = { id :: Int
+    , name :: String
+    }
+
+test1 ::
+  { id :: Unit
+  , name :: Unit
+  }
+test1 = getFieldsStandard (Proxy :: _ User)
+
+type UserComplex
+  = { id :: Int
+    , name :: String
+    , orders ::
+        Array
+          { id :: String
+          , fulfilled :: Boolean
+          , status :: Maybe String
+          , created_at :: DateTime
+          , fulfilled_at :: Maybe DateTime
+          , complaints :: Maybe (Array { subject :: String, body :: String })
+          }
+    , other_data :: Maybe Json
+    }
+
+test2 ::
+  { id :: Unit
+  , name :: Unit
+  , orders ::
+      { complaints ::
+          { body :: Unit
+          , subject :: Unit
+          }
+      , created_at :: Unit
+      , fulfilled :: Unit
+      , fulfilled_at :: Unit
+      , id :: Unit
+      , status :: Unit
+      }
+  , other_data :: Unit
+  }
+test2 = getFieldsStandard (Proxy :: _ UserComplex)