Microsoft.Compute/virtualMachines/runCommands parameters & protected parameters

[Thomas-Verschuere]

Hello, I'm trying to figure out how to use parameters & protected paramaters in the runCommands resource.

The resource allows the use of the parameters & protectedParameters properties but how do I actually reference to them in the script?

resource script 'Microsoft.Compute/virtualMachines/runCommands@2021-03-01' = {
  parent: vm
  name: 'script1'
  location: location
  properties: {
    parameters: [
      {
        name: 'param1'
        value: '10.10.10.10'
      }
    source: {
      script: '''New-Item -Path C:\AzureData\ -Name "hello.txt" -ItemType File -Value "Hello from: $param1""'''
    }
  }
}

[brwilkinson]

Can I assume you are using Windows based on the PowerShell command + the directory path?

• If you prefer to keep your scripts in a local ps1 file so they can be run and tested independently, that is what I prefer.

param vmName string = 'AEU1-PE-CTL-D1-vmJMP01'
param Location string = resourceGroup().location

resource virtualMachine 'Microsoft.Compute/virtualMachines@2022-11-01' existing = {
  name: vmName
}

resource runCommands 'Microsoft.Compute/virtualMachines/runCommands@2022-11-01' = {
  name: 'configure'
  location: Location
  parent: virtualMachine
  properties: {
    timeoutInSeconds: (60 * 90)
    parameters: [
      {
        name: 'vmName'
        value: vmName
      }
    ]
    source: {
      script: loadTextContent('configure.ps1')
    }
  }
}

contents of configure.ps1 (local script file in the same directory as my bicep file, although doesn't have to be.)

param (
    [string]$vmName
)

$PSBoundParameters
Write-Output $vmName

The following also works.

resource runCommands 'Microsoft.Compute/virtualMachines/runCommands@2022-11-01' = {
  name: 'configure'
  location: Location
  parent: virtualMachine
  properties: {
    timeoutInSeconds: (60 * 90)
    parameters: [
      {
        name: 'vmName'
        value: vmName
      }
    ]
    source: {
      script: '''
param (
    [string]$vmName
)

$PSBoundParameters

Write-Output $vmName
'''
    }
  }
}

Example of output

Get-AzVMRunCommand -ResourceGroupName AEU1-PE-CTL-RG-D1 -VMName AEU1-PE-CTL-D1-vmJMP01 -RunCommandName configure -Expand InstanceView | foreach InstanceView

ExecutionState   : Succeeded
ExecutionMessage : 
ExitCode         : 0
Output           : Key    Value
                   ---    -----
                   vmName AEU1-PE-CTL-D1-vmJMP01
                   AEU1-PE-CTL-D1-vmJMP01

Error            : 
StartTime        : 4/28/2023 1:23:28 AM
EndTime          : 4/28/2023 1:23:29 AM

You could also use $args however that is not very usable/powershell like.

    source: {
      script: '''
$args

echo "vmName is [$($args[1])]"
'''
    }

Get-AzVMRunCommand -ResourceGroupName AEU1-PE-CTL-RG-D1 -VMName AEU1-PE-CTL-D1-vmJMP01 -RunCommandName configure -Expand InstanceView | foreach InstanceView                                                                                                                                                                                   

ExecutionState   : Succeeded
ExecutionMessage : 
ExitCode         : 0
Output           : -vmName
                   AEU1-PE-CTL-D1-vmJMP01
                   vmName is [AEU1-PE-CTL-D1-vmJMP01]
Error            : 
StartTime        : 4/28/2023 1:40:08 AM
EndTime          : 4/28/2023 1:40:08 AM

This is documented over here:

• https://learn.microsoft.com/en-us/azure/virtual-machines/windows/run-command-managed#create-or-update-run-command-on-a-vm-instance-using-parameter-and-protectedparameter-parameters-public-and-protected-parameters-to-script

So just build your param block to accept those arguments for PowerShell.

Linux uses ENV vars. I found it works without having a runAsUser however not when using the runAsUser, I didn't spend much time trying to figure it out.

resource runCommands 'Microsoft.Compute/virtualMachines/runCommands@2022-11-01' = {
  name: 'configure'
  location: Location
  parent: virtualMachine
  properties: {
    timeoutInSeconds: (60 * 90)
    parameters: [
      {
        name: 'vmName'
        value: vmName
      }
    ]
    source: {
      script: '''
printenv vmName
'''
    }
  }
}

Get-AzVMRunCommand -ResourceGroupName AEU1-PE-CTL-RG-D1 -VMName AEU1-PE-CTL-D1-vmUBU01 -RunCommandName configure -Expand InstanceView | foreach InstanceView                                                                                                                                                                                   

ExecutionState   : Succeeded
ExecutionMessage : Execution completed
ExitCode         : 0
Output           : AEU1-PE-CTL-D1-vmUBU01

[brwilkinson]

I figure for the runAsUser issue on Linux, using this other method for args would be useful

from that docs link

For Nameless arguments, pass an empty string to name input. Nameless arguments are passed to script and run like this - myscript.sh publicParam1value publicParam2value secret1value secret2value

resource runCommands 'Microsoft.Compute/virtualMachines/runCommands@2022-11-01' = {
  name: 'configure'
  location: Location
  parent: virtualMachine
  properties: {
    timeoutInSeconds: (60 * 90)
    parameters: [
      {
        name: ''
        value: vmName
      }
      {
        name: ''
        value: Location
      }
    ]
    source: {
      script: '''
start=$(date)
echo "Start: [$start] is EUID [$EUID]"
echo "Start: [$start] is SUDO_UID [$SUDO_UID]"
echo "vname is [$1] and location is [$2]"
'''
    }
  }
}

Get-AzVMRunCommand -ResourceGroupName AEU1-PE-CTL-RG-D1 -VMName AEU1-PE-CTL-D1-vmUBU01  -RunCommandName configure  -Expand instanceView | foreach InstanceView                                                                                                                                                                                 

ExecutionState   : Succeeded
ExecutionMessage : Execution completed
ExitCode         : 0
Output           : Start: [Fri Apr 28 03:02:09 UTC 2023] is EUID [0]
                   Start: [Fri Apr 28 03:02:09 UTC 2023] is SUDO_UID []
                   vname is [AEU1-PE-CTL-D1-vmUBU01] and location is [eastus]

resource runCommands 'Microsoft.Compute/virtualMachines/runCommands@2022-11-01' = {
  name: 'configure'
  location: Location
  parent: virtualMachine
  properties: {
    timeoutInSeconds: (60 * 90)
    runAsUser: 'root'        // <--- Added runAsUser
    parameters: [
      {
        name: ''
        value: vmName
      }
      {
        name: ''
        value: Location
      }
    ]
    source: {
      script: '''
start=$(date)
echo "Start: [$start] is EUID [$EUID]"
echo "Start: [$start] is SUDO_UID [$SUDO_UID]"
echo "vname is [$1] and location is [$2]"
'''
    }
  }
}

Get-AzVMRunCommand -ResourceGroupName AEU1-PE-CTL-RG-D1 -VMName AEU1-PE-CTL-D1-vmUBU01  -RunCommandName configure  -Expand instanceView | foreach InstanceView                                                                                                                                                                                 

ExecutionState   : Succeeded
ExecutionMessage : Execution completed
ExitCode         : 0
Output           : Start: [Fri Apr 28 03:01:02 UTC 2023] is EUID []
                   Start: [Fri Apr 28 03:01:02 UTC 2023] is SUDO_UID [0]
                   vname is [AEU1-PE-CTL-D1-vmUBU01] and location is [eastus]

So I would say that is a nicer method with the nameless param keys.

[Thomas-Verschuere]

Thank you so much! It works now 👍🏻

Maybe this could be added to a quickstart template on https://learn.microsoft.com/en-us/azure/templates/microsoft.compute/virtualmachines/runcommands?pivots=deployment-language-bicep ?

[brwilkinson]

Yes, I'll drop them a note about it, on that docs page, good idea. Glad it's working.

[hudisrl]

Wow brilliant! 🥇