这样一种方式限制 Mint 可行么？

[v1xingyue]

如 今天 Move weekly 讨论需要使用一个 Table 来记录 mint 的address。

想到一个办法mint 来限制，大家来探讨是否可行。

1. mint 一个 coin 之前，先 mint 一个 凭证 object 。
2. mint coin 的时候，传递那个 凭证object 。并对其进行一定变更，根据凭证判断mint。

简单逻辑如下:

发卡模块，给用户凭证

module hello_world::card {
    use sui::object::{Self, UID};
    use sui::transfer;
    use sui::tx_context::{Self, TxContext};

    /// An object that contains an arbitrary string
    struct Card has key, store {
        id: UID,
        mint_count: u64
    }

    public fun add_count(card:&mut Card) {
        card.mint_count = card.mint_count + 1
    }

    public fun card_count(card:&Card) : u64 {
        card.mint_count
    }

    public entry fun mint(ctx: &mut TxContext) {
        let object = Card {
            id: object::new(ctx),
            mint_count: 0
        };
        transfer::public_transfer(object, tx_context::sender(ctx));
    }

}

coin 模块

module hello_world::limitcoin {

    use sui::coin::{Self};
    use sui::tx_context;
    use std::option;
    use sui::transfer;
    use sui::balance;

    use sui::tx_context::sender;
    use sui::object::{Self, UID};

    use hello_world::card::{Self,Card};

    struct MySupply has key,store{
        id: UID,
        supply: balance::Supply<LIMITCOIN>
    }

    // witness
    struct LIMITCOIN has drop {}

    fun init(witness: LIMITCOIN, ctx: &mut tx_context::TxContext){
        let (cap, metadata)=  coin::create_currency(
            witness,
            4,
            b"LIMITCOIN",
            b"LIMITCOIN",
            b"This is Limited Token",
            option::none(),
            ctx,
        );
        transfer::public_share_object(metadata);
        let supply = coin::treasury_into_supply(cap);
        transfer::public_share_object(MySupply{
            id: object::new(ctx),
            supply
        });
    }

    public entry fun mint(card:&mut Card, supply:&mut MySupply,value: u64,ctx: &mut tx_context::TxContext){
        card::add_count(card);
        // 这里可以加判断逻辑.
        let balance = balance::increase_supply(&mut supply.supply,value);
        let coin = coin::from_balance(balance, ctx);
        transfer::public_transfer(coin, sender(ctx));
    }


}

注: 为方便测试，直接share 的 MySupply, 就是个水龙头。 线上环境慎用，慎用 !!!!!!

[fyang1024]

Card 结构里除了mint的次数mint_count外，还可以添加总共mint的数量amount、上次mint的时间minted_at之类的字段，这样在limitcoin模块的mint函数里可以对mint行为做更加精细的控制，除了一个地址最多mint多少次，还可以控制一个地址最多mint多少数量的limitcoin，两次mint的间隔至少多久。

每个Card对mint limitcoin是可以精细控制的，但由于任何人可以无限mint新的Card，所以这变成怎样控制每个地址可以mint多少卡的问题，感觉还是绕不开一张表来记录每个地址的mint card的记录。